Глава 2. Таймеры и звук.

Раздел 2. Создание звука.

2.2.5 Генерация набора тонов.

В этом подразделе показано как генерировать цепочку звуков, когда компьютер ничем другим не занят; в следующем будет показано как выполнить ту же задачу, когда компьютер занят другой работой. Kогда компьютер ничем другим не занят, то можно выводить мелодию или производить специальные звуковые эффекты; когда же компьютер занят другой работой, то нельзя производить звуковые эффекты.

Создание звуковых строк является одной из мощнейших возможностей, предоставляемых Бейсиком. Построение же строк звуков в ассемблере требует большой работы. Может быть использован любой из двух методов генерации звука, предложенных в {2.2.2} и {2.2.3}. Для обоих методов надо просто генерировать один тон в течении заданного времени, затем следующий и т.д. Kаждая звуковая строка формируется из двух строк данных, одна из которых содержит частоты последовательных тонов, а другая хранит их длительности (при условии, что требуются разные длительности). Продолжительность звучания определяется с использованием счетчика времени суток BIOS {2.1.6}.

Hизкий уровень.

В примере для генерации звука используется микросхема таймера 8253. Здесь просто исполняются 8 нот, но небольшая модификация может сильно расширить возможности этой процедуры. Имеется три строки данных. Первая устанавливает длительность каждой ноты, как кратное произвольного периода задержки (изменяя этот период задержки, можно изменять темп). Вторая строка содержит частоты каждой из 8 нот; эти значения должны быть помещены в регистр задвижки канала 2 микросхемы 8253 для исполнения желаемых тонов. Третья строка содержит мелодию в виде кодовых номеров от 1 до 8, которые соответствуют восьми частотам. Эта строка завершается кодом 0FFH, который служит признаком конца мелодии. Процедура просто читает очередную ноту мелодии, находит соответствующую частоту и помещает ее в канал 2. Затем длительность для этой ноты помещается в счетчик цикла задержки, который использует счетчик времени суток, а когда задержка кончается, то переходим к обработке следующей ноты. Hа рис. 2-5 показана работа этой процедуры.

	;---в сегменте данных
BEAT DB 10,9,8,7,6,5,4,3,2	;длительность нот
FREQUENCY DW 2280,2031,1809,1709	;таблица частот
DW 1521,1353,1207,1139	;
MELODY DB 1,2,3,4,5,6,7,8,0FFH	;номер частоты ноты
	;---инициализация
PORT_B EQU 61H
COMMAND_REG EQU 43H
LATCH2 EQU 42H
IN AL,PORT_B	;получаем текущий статус
OR AL,00000011B	;разрешаем динамик и таймер
OUT PORT_B,AL	;заменяем байт
MOV SI,0	;инициализируем указатель
MOV AL,0B6H	;установка для канала 2
OUT COMMAND_REG,AL	;посылаем в командный регистр
	;---смотрим ноту, получаем ее частоту и помещаем в канал 2
NEXT_NOTE: LEA BX,MELODY	;берем смещение для мелодии
MOV AL,[BX][SI]	;берем код n-ной ноты строки
CMP AL,0FFH	;проверка на конец строки
JE NO_MORE	;если конец, то на выход
CBW	;переводим в слово
	;получение частоты
MOV BX,OFFSET FREQUENCY	;смещение таблицы частот
DEC AX	;начинаем отсчет с 0
SHL AX,1	;умножаем на 2, т.к. слова
MOV DI,AX	;адресуем через DI
MOV DX,[BX][DI]	;получаем частоту из таблицы
	;начинаем исполнение ноты
MOV AL,DL	;готовим младший байт частоты
OUT LATCH2,AL	;посылаем его
MOV AL,DH	;готовим старший байт частоты
OUT LATCH2,AL	;посылаем его
	;---создание цмкла задержки
MOV AH,0	;номер функции чтения счетчика
INT 1AH	;получаем значение счетчика
MOV BX,OFFSET BEAT	;смещение таблицы длин
MOV CL,[BX][SI]	;берем длину очередной ноты
MOV CH,0	;
MOV BX,DX	;берем младшее слово счетчика
ADD BX,CX	;определяем момент окончания
STILL_SOUND: INT 1AH	;берем значение счетчика
CMP DX,BX	;сравниваем с окончанием
JNE STILL_SOUND	;неравны - продолжаем звук
INC SI	;переходим к следующей ноте
JMP NEXT_NOTE	;
	;---завершение
NO_MORE: IN AL,PORT_B	;получаем статус порта B
AND AL,0FCH	;выключаем динамик
OUT 61H,AL	;заменяем байт

<~-2.2.4 Гудок динамика.
Содержание
2.2.6 Генерация строки тонов, одновременно с другими операциями.-~>